Controle Inteligente para Abastecimento de Caixa D’Água com Arduino Nano

Para utilizar o display LCD 16×2 com interface I2C é necessário usar a biblioteca Liquid_Crystal_I2C e Wire, se não tiver instalada na sua IDE Arduino você pode instalar seguindo os seguintes passo: Para instalar a biblioteca, abra a IDE, vá até o menu Sketch -> Incluir Biblioteca -> Gerenciar Bibliotecas. No gerenciador de bibliotecas, busque por liquidcrystal e instale a biblioteca LiquidCrystal I2C desenvolvida por Arduino, o mesmo para a Wire.

/**
 * @file Controle_de_abastecimento_da_Caixa_da_agua.ino
 * @author Saulo Aislan (aislansaulo@gmail.com)
 * @brief Firmware para o o controle e monitoramento do abastecimento de uma caixa de água
 *        com sensor de fluxo, display LCD e Relé.
 * @version 0.1
 * @date 2025-02-10
 *
 * @copyright Copyright (c) 2025
 *
 */

#include <Arduino.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h> 

// Definições de pinos
const float SENSOR_FLUXO_PIN = 3;   // Pino do sensor de fluxo/vazão
const float RELE_BOMBA_PIN = 5;     // Pino do relé da bomba
const float BOTAO_AUMENTAR_PIN = 6; // Botão para aumentar a quantidade
const float BOTAO_DIMINUIR_PIN = 2; // Botão para diminuir a quantidade
const float BOTAO_INICIAR_PIN = 9;  // Botão para iniciar o fluxo/vazão

const float LIMITE_MAXIMO_LITROS = 1000;  // Limite máximo de litros
const float LIMITE_MINIMO_LITROS = 10;    // Limite mínimo de litros
const float INCREMENTO_LITROS = 10;       // Incremento/decremento em litros
const float FATOR_MULTIPLICADOR_BOTAO = 10; // Fator multiplicador para o Incremento/decremento dos botões
// definicao do fator de calibracao para conversao do valor lido
const float FATOR_CALIBRACAO = 4.5;

// Variáveis globais
volatile int pulsos = 0;       // Contador de pulsos do sensor de fluxo/vazão
float litros_desejados = 0;    // Quantidade inicial desejada (em litros)
int incremento_litros = INCREMENTO_LITROS;    // Incremento/decremento em litros

//definicao das variaveis de fluxo/vazão e volume
float vazao = 0;        // variavel para armazenar o valor da vazao
float volume = 0;       // variavel para armazenar o valor de volume
float volume_total = 0; // Quantidade de água medida pelo sensor de fluxo/vazão

//definicao da variavel de intervalo de tempo
unsigned long tempo_antes = 0;

// Debounce dos botões
unsigned long debounce_delay = 200;
unsigned long ultimo_tempo_botao = 0;

LiquidCrystal_I2C lcd(0x3F, 16, 2);

// Protótipos de funções
void iniciarAbastecimento(void);

// Função de interrupção para contar pulsos
void contadorPulsos(void) {
  pulsos++;
}

/**
 * @brief Setup do Arduino, inicializa as configurações iniciais
 * 
 */
void setup() {
  // Configuração dos pinos
  pinMode(SENSOR_FLUXO_PIN, INPUT);
  pinMode(RELE_BOMBA_PIN, OUTPUT);
  pinMode(BOTAO_AUMENTAR_PIN, INPUT_PULLUP);
  pinMode(BOTAO_DIMINUIR_PIN, INPUT_PULLUP);
  pinMode(BOTAO_INICIAR_PIN, INPUT_PULLUP);

  // Inicialização
  digitalWrite(RELE_BOMBA_PIN, LOW);

  // Configuração da interrupção do sensor de fluxo/vazão
  attachInterrupt(digitalPinToInterrupt(SENSOR_FLUXO_PIN), contadorPulsos, FALLING);

  // Inicializa a comunicação serial
  Serial.begin(115200);

  // Inicializa o display LCD
  lcd.init(); 
  lcd.backlight();
  lcd.setCursor(0, 0);        // selecionando coluna 0 e linha 0
  lcd.print("Controle de");   // print da mensagem
  lcd.setCursor(0, 1);        // selecionando coluna 0 e linha 0
  lcd.print("Abastecimento!");// print da mensagem

  Serial.print("Controle de abastecimento de Caixa d’Água");
}

/**
 * @brief Loop principal do Arduino, onde é feito
 * o controle do abastecimento atraves dos botões
 * 
 */
void loop() {
  // Leitura e ajuste da quantidade desejada
  if (digitalRead(BOTAO_AUMENTAR_PIN) == LOW && millis() - ultimo_tempo_botao > debounce_delay) {
    litros_desejados += incremento_litros; // Incrementa em litros inteiros
    litros_desejados = constrain(litros_desejados, LIMITE_MINIMO_LITROS, LIMITE_MAXIMO_LITROS); // Limita entre 1 e 10 litros
    ultimo_tempo_botao = millis();

    lcd.clear();                       // limpa a tela
    lcd.setCursor(0, 0);               // selecionando coluna 0 e linha 0
    lcd.print("Litros desejados: ");   // print da mensagem
    lcd.setCursor(2, 1);               // selecionando coluna 2 e linha 1
    lcd.print(litros_desejados);       // Print da mensagem

    Serial.print("Litros desejados: ");
    Serial.println(litros_desejados);
  }

  if (digitalRead(BOTAO_DIMINUIR_PIN) == LOW && millis() - ultimo_tempo_botao > debounce_delay) {
    litros_desejados -= incremento_litros; // Decrementa em litros inteiros
    litros_desejados = constrain(litros_desejados, LIMITE_MINIMO_LITROS, LIMITE_MAXIMO_LITROS); // Limita entre 1 e 10 litros
    ultimo_tempo_botao = millis();

    lcd.clear(); 
    lcd.setCursor(0, 0);               // selecionando coluna 0 e linha 0
    lcd.print("Litros desejados: ");   // print da mensagem
    lcd.setCursor(2, 1);               // selecionando coluna 2 e linha 1
    lcd.print(litros_desejados);       // Print da mensagem

    Serial.print("Litros desejados: ");
    Serial.println(litros_desejados);
  }

  // Inicia o Abastecimento de água ao pressionar o botão iniciar
  if (digitalRead(BOTAO_INICIAR_PIN) == LOW && litros_desejados > 0) {
    iniciarAbastecimento();
  }
}

/**
 * @brief Função para iniciar o abastecimento de
 * água e controlar a vazão e a bomba de água
 * 
 */
void iniciarAbastecimento() {
  pulsos = 0;
  volume_total = 0;

  // Ativa a bomba
  digitalWrite(RELE_BOMBA_PIN, HIGH);

  Serial.println("Iniciando Abastecimento...");

  // Aguarda até atingir a quantidade desejada
  while (volume_total < litros_desejados) {
    // Verifica se o sensor de fluxo/vazão está funcionando
    if (pulsos == 0) {
      continue;
    } 
    
    //Executa a contagem de pulsos uma vez por segundo
    if((millis() - tempo_antes) > 1000){

      //conversao do valor de pulsos para L/min
      vazao = ((1000.0 / (millis() - tempo_antes)) * pulsos) / FATOR_CALIBRACAO;

      //Exibe na serial
      Serial.print("Vazao de: ");
      Serial.print(vazao);
      Serial.println(" L/min");

      //calculo do volume em litros passado pelo sensor
      volume = vazao / 60; // Conversão de L/min para L/s
      volume_total += FATOR_MULTIPLICADOR_BOTAO * volume;  //armazenamento do volume total passado pelo sensor

      //Exibe na serial
      Serial.print("Volume: ");
      Serial.print(volume_total);
      Serial.println(" L");
      Serial.println();
    
      lcd.clear();               // limpa a tela
      lcd.setCursor(0, 0);       // selecionando coluna 0 e linha 0
      lcd.print("Vazao: ");      // print da mensagem
      lcd.print(vazao, 1);       // print o valor da vazão
      lcd.print(" L/min");       // print da mensagem
      lcd.setCursor(0, 1);       // selecionando coluna 2 e linha 1
      lcd.print("Vol.Total: ");  // print da mensagem
      lcd.print(volume_total, 1);// Print o volume total
      lcd.print(" L");           // print da mensagem

      // Reinicialização do contador de pulsos
      pulsos = 0;

      // Atualização da variavel tempo_antes
      tempo_antes = millis();
      }

    if (volume_total >= litros_desejados) {
      break;
    }
  }

  // Desliga a bomba
  digitalWrite(RELE_BOMBA_PIN, LOW);

  lcd.clear();
  lcd.setCursor(0, 0);                     // selecionando coluna 0 e linha 0
  lcd.print("Abastecimento");              // print da mensagem
  lcd.setCursor(0, 1);                     // selecionando coluna 0 e linha 1
  lcd.print("Concluido!");                 // print da mensagem
  Serial.println("Abastecimento concluído!");
}